Można wysyłać dowolne maile z Gmail dowolnymi załącznikami używając VBA, na bazie poniższego kodu:

Option Explicit

'============================================================
' Wymaga referencji do Microsoft CDO for Windows 2000 Library

' Przy pierwszym uruchomieniu jest blokowane przez Gmail
' Gmail wysyła maila o próbie użycia konta
' W tym mailu daje link umożliwiający działanie tego kodu
' https://www.google.com/settings/security/lesssecureapps
' z ostrzeżeniem, że konto nie będzie dłużej chronione
' zgodnie z nowoczesnymi standardami. - wybór należy do nas :)
'=============================================================
Sub WyslijGmail()
    Dim MojMail As New CDO.Message
    Const ADRES As String = _
        "http://schemas.microsoft.com/cdo/configuration/"
    
    On Error GoTo Obsluga
    
    With MojMail.Configuration.Fields
        .Item(ADRES & "smtpusessl") = True
        .Item(ADRES & "smtpauthenticate") = 1
        .Item(ADRES & "smtpserver") = "smtp.gmail.com"
        .Item(ADRES & "smtpserverport") = 25
        .Item(ADRES & "sendusing") = 2
        .Item(ADRES & "sendusername") = "twoje_konto@gmail.com"
        .Item(ADRES & "sendpassword") = "twoje_haslo"
        .Update
    End With
    With MojMail
        .Subject = "Temacik"
        .To = "konto_odbiorcy@gmail.com"
        .From = "twoje_konto@gmail.com"
        .TextBody = "Pozdrowienia z VBA przez Gmail :)"
        .AddAttachment "C:\EX04\test.txt"
        .Send
    End With
    
    MsgBox "Poszło :)"
    
Czyszczenie:
    On Error Resume Next
    Set MojMail = Nothing
    Exit Sub
Obsluga:
    MsgBox Err & " - " & Err.Description
    Resume Czyszczenie
End Sub